link/x86_64-elf.ld


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60

OUTPUT_FORMAT(elf64-x86-64)
OUTPUT_ARCH(i386:x86-64)

ENTRY(_start)

PAGESIZE = CONSTANT(MAXPAGESIZE);

PHDRS
{
    limine_requests PT_LOAD;
    text    PT_LOAD;
    rodata  PT_LOAD;
    data    PT_LOAD;
    bss     PT_LOAD;
}

SECTIONS
{
    . = 0xFFFFFFFF80000000;
    _kernel_start = .;

    _kernel_text_start = .;
    .text : {
        *(.init)
        *(.text .text.*)
        *(.fini)
    } :text
    _kernel_text_end = .;
    . = ALIGN(PAGESIZE);

    _kernel_rodata_start = .;
    .rodata : {
        *(.rodata .rodata.*)
    } :rodata
    _kernel_rodata_end = .;
    . = ALIGN(PAGESIZE);

    _kernel_data_start = .;
    .data : {
        *(.data .data.*)
        *(.limine_requests)
    } :data
    _kernel_data_end = .;
    . = ALIGN(PAGESIZE);

    _kernel_bss_start = .;
    .bss : {
        *(COMMON)
        *(.bss .bss.*)
    } :bss
    _kernel_bss_end = .;

    /DISCARD/ : {
        *(.eh_frame*)
        *(.note .note.*)
    }

    _kernel_end = .;
}