link/x86_64-jove.ld


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

OUTPUT_FORMAT(elf64-x86-64)
OUTPUT_ARCH(i386:x86-64)

ENTRY(_start)

PAGESIZE = CONSTANT(MAXPAGESIZE);

PHDRS
{
    text    PT_LOAD FLAGS((1 << 0) | (1 << 2)) ; /* RO EX*/
    rodata  PT_LOAD FLAGS((1 << 2)) ;            /* RO*/
    data    PT_LOAD FLAGS((1 << 1) | (1 << 2)); /* RW*/
    bss     PT_LOAD FLAGS((1 << 1) | (1 << 2)); /* RW*/
}

SECTIONS
{
    . = 0xFFFFFFFF80000000;
    _kernel_start = .;

    .text BLOCK(PAGESIZE) : ALIGN(PAGESIZE) {
        *(.init)
        *(.text .text.*)

        . = ALIGN(8);
        _kernel_ctors_start = .;
        *(.ctors)
        _kernel_ctors_end = .;

        *(.fini)
    } :text

    .rodata BLOCK(PAGESIZE) : ALIGN(PAGESIZE) {
        *(.rodata .rodata.*)
    } :rodata

    .data BLOCK(PAGESIZE) : ALIGN(PAGESIZE) {
        *(.data .data.*)
    } :data

    .bss BLOCK(PAGESIZE) : ALIGN(PAGESIZE) {
        *(COMMON)
        *(.bss .bss.*)
    } :bss

    /DISCARD/ : {
        *(.note .note.*)
    }

    _kernel_end = .;
}